; Programme prévu pour un PicAxe 08M2.
                   ; Langage = BASIC standardisé à la norme PicAxe.
                   ;
                   ; Notes
                   ; =====
                   ;
                   ;
                   ;
                   ; Créateur : Meuh sur cyclurba.fr (2012-BMS ver.28)
                   ; --------
                   
                   
init:                   
                   
                   
                   
                   
                   ; Définition des sorties utilisées
low C.2            ; décharge = composé de :
                   ; - Transitor en boitier TO92 Extended du modèle BCU83F
                   ; - R de base de 68 Ohms métal
                   ; - R de décharge de 3,3 Ohms Céramique/Cément de 5w 
                   ; - la R de décharge atteint 100-130°C à 25°C
                   ; - C.2 supporte le PWM (signal carré en arrière plan)
                   
low C.1            ; rouge
low C.4            ; vert
                   ; Ces 2 sorties pilotent 1 seul LED bi-couleur 3v + R de 1k
                   ; On ne peut donc pas les activer en même temps
                   ; Si on le fait, la LED reste éteinte

low C.0            ; Buzzer : composé de :
                   ; - Transitor en boitier TO92 Extended du modèle BCU83F
                   ; - R de base de 68 Ohms métal
                   ; - Buzzer de 3-6v DC à 82dB (équivalent aux Lipo-Alarm)          
                   
                   ; Variables utilisées dans le programme
let w13 = 0        ; tension brute (CalibADC10)
let w12 = 0        ; tension en mV (calculée)
let w11 = 0        ; tension en mV durant le cycle dodo
let w10 = 0        ; Consigne PWM variable
let w9 = 0         ; variable d'opération mathématique
let w8 = 0         ; variable d'opération mathématique


let b0 = 0         ; Signalisation seuil trophaut
let b1 = 0         ; Comptage pour applanir
let b2 = 0         ; Comptage cycle dodo
let b3 = 0         ; Signalisation tension
let b4 = 0         ; Comptage indication mesure tension
let b5 = 0         ; Filtrage seuil haut
let b6 = 0         ; Signalisation seuil tropbas
let b7 = 0         ; millier de mV
let b8 = 0         ; centaine de mV
let b9 = 0         ; dizaine de mV



                   ; ATTENTION : dans le programme, les b0-b1-b2 ... ne peuvent
                   ; pas avoir plus que 255 puis ils repassent à 0 sans votre
                   ; accord.
                   ; PAREIL pour les w0-w1-w2 ... qui ne peuvent pas avoir plus
                   ; de 65535 puis ils repassent à 0 sans votre accord.





pause 4000         ; pause de démarrage pour le séquençage de multiples picaxes
                   ; 0 = pic1, 500 = pic2, 1000 = pic3 ... etcs ...






                   ; contrôle des signalisations du BMS

                   
High C.0 : pause 200 : low C.0 : pause 200 ; Test Buzzer

High C.4 : pause 500 : low C.4 : pause 200 ; Test LED verte

High C.1 : pause 500 : low C.1 : pause 200 ; Test LED rouge

do                                         ; Test R décharge en PWM
inc w10 : pwmout C.2, 49, w10  
loop until w10=200
do
dec w10 : pwmout C.2, 49, w10  
loop until w10=0

pwmout C.2, OFF





              
                   
main:                     ; Démarrage du BMS mono-cellule


calibadc10 w13            ; lecture de la tension interne du PicAxe
let w12 = 52429/w13*20+10    ; calcul de la tension réelle en mV


if w12>=3800 then         ; tension seuil trop haut (Lipo:4,22v LifePO4:3,8v)
goto trophaut
endif

if w12=<2700 then         ; tension seuil trop bas (Lipo:3,0v LifePO4:2,5v)
goto tropbas
endif


if w12>=3650 then         ; tension d'équilibrage (Lipo:4.20v LifePO4:3,65v)
goto volthaut
endif


if w12<3650 then          ; tension d'équilibrage à l'identique du dessus
goto voltbas
endif


goto main







trophaut:                      ; décharge, clignotement rapide rouge et Buzzer

inc b5

let w10=200
pwmout C.2, OFF
High C.2
low C.4

if b5>5 then
let b0=6
do
High C.1 : toggle C.0 : pause 100 : low C.1 : pause 100
dec b0
loop until b0=0
endif

pause 1000
low C.2

goto main






tropbas:                      ; clignotement rouge et vert + Buzzer (long)

let b2=0
let b4=0
let b5=0
let w10=0

pwmout C.2, OFF

let b6=5
do
High C.1 : High C.0 : pause 300 : low C.1 : pause 300
High C.4 : pause 300 : low C.4 : low C.0 : pause 300
dec b6
loop until b6=0

goto main





volthaut:

let b2=0                     ; Reset cycle dodo
let b4=0                     ; Reset indicateur de niveau
let b5=0

inc b1

If w10=>60 then               ; Indiquer un niveau haut en rouge fixe
High C.1
low C.4
endif

If b1=200 then               ; Applani plus vite la tension
pwmout C.2, OFF
High C.2
pause 5000
low C.2
let b1=0
goto main
endif

pwmout C.2, 49, w10

if w10=200 then
goto main
endif

inc w10                      ; Augmenter la puissance de décharge

goto main






voltbas:

let b5=0

if w10=0 then                ; si la décharge est déjà arrêtée, aller en dodo
goto dodo
endif

If w10=<40 then               ; Indiquer un niveau normal en vert fixe
High C.4
low C.1
endif

pwmout C.2, 49, w10

dec w10                      ; Diminuer la puissance de décharge

goto main






dodo:

low C.4                   ; Tout éteindre et compter le cycle dodo
low C.1
low C.0
let b1=0
pwmout C.2,OFF
inc b2

sleep 4                   ; Ralentir le pic

If b2=7 then             ; Niveau que après 1 minute d'hibernation


If b4=0 or b4=10 then     ; Donner une tension non-fantôme (après 10 min)
let w10=0
do
inc w10 : pwmout C.2, 49, w10   ; Suppression tension fantôme pour une lecture
loop until w10=200              ; Montée graduelle pour éviter les EMI sur les
pause 1000                      ; autres PIC lorsqu'ils sont à coté
calibadc10 w13            ; lecture de la tension interne du PicAxe
let w11 = 52429/w13*20+10    ; calcul de la tension réelle en mV
let b4=0
let w10=0
pwmout C.2,OFF
endif

inc b4

If w12<w11 then                 ; Si la tension descend, indiquer la vrai tension
let w11=w12                     ; mesurée toutes les 10s au lieu de celle toutes
endif                           ; les 10 min

pause 2000
     
     
     
     
                                ; Indication niveau batterie stable
let b7=w11/1000                 ; calcul du millier de mV
let w9=b7*1000
let b8=w11-w9/100               ; calcul du centaine de mV
if b8>9 then : let b8=0 : endif
let w8=b8*100
let b9=w11-w9-w8/10             ; calcul du dizaine de mV
if b9>9 then : let b9=0 : endif




do
High C.4 : pause 150 : low C.4 : pause 500
dec b7
loop until b7=0

pause 1000





if b8=0 then
High C.4 : pause 500 : low C.4 : pause 500
goto diz
endif

do
High C.4 : pause 150 : low C.4 : pause 500
dec b8
loop until b8=0

pause 1000





diz:

if b9=0 then
High C.4 : pause 500 : low C.4 : pause 500
goto unit
endif

do
High C.4 : pause 150 : low C.4 : pause 500
dec b9
loop until b9=0






unit:

let b2=0

endif

goto main